- sziku69: Szólánc.
- Luck Dragon: Asszociációs játék. :)
- sziku69: Fűzzük össze a szavakat :)
- hcl: Kelj fel komám, ne aludjál
- LordAthis: Ismét egy "Idióta" A.I. Projekt, hogy meglovagolja az aktuális trendeket...
- Geri Bátyó: Agglegénykonyha 1 – rizseshús másképp
- bambano: Bambanő háza tája
- Kalacskepu: Elrontott Radeon X1950 Pro megjavítása
- GoodSpeed: Bye PET Palack, hello SodaStream
- talmida: Változások
-
LOGOUT
A Microsoft Excel topic célja segítséget kérni és nyújtani Excellel kapcsolatos problémákra.
Kérdés felvetése előtt olvasd el, ha még nem tetted.
Új hozzászólás Aktív témák
-
Mutt
senior tag
válasz
underdark
#54617
üzenetére
Szia,
Kimutatást javasoljuk erre.
Az újabb Excel-ekben képlettel is lehetséges már.
E2-ben a képlet: =KIMUTATÁS.ALAP.SZERINT(Table1[Name];Table1[Year];Table1[ASC];SZUM;0;0;;0)Van egy másik képletem is de sokkal hosszabb.
=LET(nevek;SORBA.RENDEZ(EGYEDI(Table1[Name]));
evek;SORBA.RENDEZ(EGYEDI(Table1[Year]));
sorszam;SORSZÁMLISTA(DARAB2(nevek));
ertekek;REDUCE(TRANSZPONÁLÁS(evek);sorszam;LAMBDA(s;c;FÜGG.HALMOZÁS(s;TRANSZPONÁLÁS(SZUMHATÖBB(Table1[ASC];Table1[Name];INDEX(nevek;c);Table1[Year];evek)))));
VÍZSZ.HALMOZÁS(FÜGG.HALMOZÁS("";nevek);ertekek))A képletben az "ertekek" sorban van a lényeg, ami a SZUMHATÖBB segítségével kiszámolja mindegyik névhez és évhez az értéket. A REDUCE-t arra használom, hogy a kapott értékeket "egymásra tegyem" (függőleges halmozás), mert ezt tudom majd a munkalapra kiírni. A végén még az elejére teszem a neveket.
üdv
-
Fferi50
Topikgazda
válasz
underdark
#54617
üzenetére
Szia!
Még egy lehetőség: Kimutatást készítesz, ahol a name lesz a sorcimke, a year az oszlopcimke és az asc oszlop összege lesz az értékek mezőben. Mivel minden név és év egy számot tartalmaz, így a kimutatás névsorosan fogja az éves értékeket mutatni.
Az összegző sorokat megjelenítését ki kell venned a kimutatásból (kimutatáson állva - Tervezés - Végösszegek - kikapcsolva sorokban és oszlopokban).
Ha új sort vittél be a táblázatba, akkor a kimutatást is frissítened kell, ennyi a hátránya.
Üdv. -
Fferi50
Topikgazda
válasz
underdark
#54617
üzenetére
Szia!
Ettől tartottam... (nem a kuszábbá válástól, hanem az adatok ilyen struktúrájától).
Ebben az esetben nem használható gazdaságosan az XKERES függvény, mivel mindig csak egy találatot ad vissza.
Mivel legalább 2021-es Exceled van, ezért használni tudod az EGYEDI és a SZŰRŐ függvényeket.
Az A1 : C5 tartományt átalakítottam táblázattá, hogy a táblázatos címzést tudjam használni.
Az éveket az I1 cellától a következő képlettel kaphatod meg:=TRANSZPONÁLÁS(EGYEDI(Táblázat1[year]))
Az E1 cellába írtam be a kívánt nevet.
Ezután az I2 cellában a képlet (ezt látod a képen is):=SZŰRŐ(Táblázat1[[#Mind];[asc]];(Táblázat1[[#Mind];[name]]=$E$1)*(Táblázat1[[#Mind];[year]]=I$1);0)
Ezt a képletet másolni és beilleszteni kell a mellette levő cellákba (nem pedig egérrel húzni!) és akkor megfelelően működik.
Figyelned kell a $ jelekre a cella címzésekben!
Remélem, tudod alkalmazni a saját táblázatodra. Ha nem sikerülne, küldd el privát üziben.
Kiegészítés: Ha a neveket is egy listában szeretnéd látni, akkor a képlet a képen a H2 cellába:=EGYEDI(Táblázat1[name])
Az I2 cella képlete pedig a következő:=SZŰRŐ(Táblázat1[[#Mind];[asc]];(Táblázat1[[#Mind];[name]]=$H2)*(Táblázat1[[#Mind];[year]]=I$1);0)
A nevek helyzetének figyelembe vételével változott.
A képlet az I2 cella mellett levő cellákba másolás - beillesztés továbbra is a megfelelő mód, utána lefelé mindhárom oszlop egyszerre húzható.Üdv.
-
underdark
aktív tag
válasz
Fferi50
#54616
üzenetére
Kösz, de ez így most még kuszább lett
Megprbálom felvázolni inkább így,
Van az adattáblázat, ez egy nagyobb terjedelmű, nem így vannak az oszlopok sorban, nekem csak ez a 3 kell belőle, de az elrendezés az így van soronként a dátumok stb.
Az eredményt azt most én írtam be, hogy oda kéne nekem az a függvény
Köszi!
-
Fferi50
Topikgazda
válasz
underdark
#54615
üzenetére
Szia!
Az XKERES függvény jelen esetben a találat sorában levő értékeket tud visszaadni, az FKERES függvényhez hasonlóan, vagyis az A3 cellában levő név sorát veszi alapul.
A "belső" XKERES függvényed ugyanazon táblázat másik oszlopából fog eredményt keresni, ami nem feltétlenül azonos a külső XKERES által megadott sorral!
Ha sor és oszlop találkozásra vagy kíváncsi (ha az évek oszloponként vannak), akkor a belső XKERES függvény keresési tömbjénél a táblázat FEJLÉC-ét kell megadnod, nem az egész táblázatot (ha egérrel csinálod a tartomány kijelölését, akkor mutatni fogja a helyes szintaxist a fejlécre).
Amit a képen mutatsz, az a belső XKERES függvény eredménye - ezt nem tudja a külső függvény értelmezni. Az ablak alsó sorában egy üres = sort látsz, ott lenne a teljes képlet eredménye.
Remélem, jól értelmeztem a kérdést, ha mégsem így lenne, kérlek mutasd meg képen a Táblázat7 egy részletét a "bal felső" sarkából kiindulva (természetesen fals adatokkal).
Üdv. -
dm1970
aktív tag
Szia!
Hétvégén sajnos nem volt időm foglalkozni a próbával, s csak most jutottam el idáig.
Nagy-nagy köszönet, szokás szerint minden tökéletes.
Azért arra szeretnék egy kis időt szánni, hogy feltérképezzem, hogy hogyan működik, mit jelentenek a beállítások.#54611jjohn
Igen, ezt írtam én is.
Köszi Neked is!
Szerintem, ha egy cellában van, akkor a bal5, jobb5 használatával a C1, B1 behelyettesíthető. Kíváncsiságból ki fogom próbálni. -
sopruk
senior tag
Köszönöm a további infókat, tippeket!
Sokat tanultam e probléma kapcsán.
Csak alap dolgokra használom az Excel-t, néhány képletet ismerek
De a mostani keresgélés kapcsán, oktató videók segítségével is felfedeztem pár új hasznos dolgot, ami könnyíti a munkát. Lesz időm nézegetek még ilyeneket, érdemes fejlődni ebben is...
-
jjohn
aktív tag
válasz
dm1970
#54604
üzenetére
Szia!
Annyit tudok segíteni, ha a munkaidő kezdete és vége más cellában van.
Akkor ez egy működő megoldás, én ezt használom, percre pontosan kiszámítja a munkával töltött időt.
A szünetekkel variálhatsz a képletben a 40 percet átírhatod 45-re stb.
= (C1-B1) - HA((C1-B1) < IDŐ(8;0;0); 0; HA((C1-B1) < IDŐ(10;0;0); IDŐ(0;20;0); IDŐ(0;40;0)))
-
-
dm1970
aktív tag
Szia!
Köszi!
Nem sok időm volt tesztelni, de nem tudtam belőle kihozni azt amit szerettem volna. Ránézésre, a legnagyobb gond az, hogy az én táblázatomban a kezdő és a vég időpont 1 cellában van. Próbáltam az általam használt képletből behelyettesíteni az elsőidőpárt B1-nek a másodikat C1-bek, de nem megy, és nem látom át a képletedet (mondjuk az enyémet se nagyon )#54607Mutt
Neked is köszi!
A kép alapján tökéletes, de sajna 2016 Office van, s ahogy elnézem, ebben ezek közül csak a maradék függvény található meg.dm
-
Mutt
senior tag
válasz
sopruk
#54602
üzenetére
Szia,
A keres függvények csak azonos adattípuson (szám vs. szöveg) műkődnek helyesen.
Amikor két külön helyről van adatsorod, akkor sokszor előfordul hogy a típusok eltérőek (
a számok szövegként vannak tárolva).Esete válogatja hogy mi a jó megoldás, de csinálhatod hogy az XKERES-ben azonnal típuskonverziót végzel:
1) mind a keresett, mind a keresési tartományt szöveggé alakítod azzal hogy üres szöveget fűzől hozzájuk:=XKERES([@Termékkód]&"";csv_data[termékkód]&"";csv_data[összeg])
2) mindent számmá alakítasz egy szorzással:=XKERES([@Termékkód]*1;csv_data[termékkód]*1;csv_data[összeg])Ha a keresési tartomány sok adatot tartalmaz (kb. 50 ezer sor felett van), akkor gyorsabb megoldás, a tartomány mellé egy új oszlopban végzed el a típus átalakítást és azt használod fel kereséshez.
Hasonló technikát lehet használni pl. felesleges szóközök miatti hibák esetén a TISZTÍT függvénnyel.
=XKERES(TISZTÍT([@Termékkód]);TISZTÍT(csv_data[termékkód]);csv_data[összeg])üdv
-
Mutt
senior tag
válasz
dm1970
#54604
üzenetére
Szia,
...időpár alapján kiszámolja a tényleges munkaidőt a munkaközi szüneteket kiveszi belőle...
1) Az eltelt időszámítására a legbiztossabb megoldás a MARADÉK / MOD függvény használata. MARADÉK(vége-eleje;1)*24
2) Érdemes a HAELSŐIGAZ / IFS függvényt használni, ha több vizsgálatod is van a képletben.Ezek után, ha újabb Exceled van (Excel 2021 vagy újabb), akkor a LET függvénnyel áttekinthetőbbé tehetjük az egészet:
=LET(input;B1;kezdete;BAL(input;5);vege;JOBB(input;5);kulonbseg;MARADÉK(vege-kezdete;1)*24;kulonbseg-HAELSŐIGAZ(kulonbseg>9+45/60;45;kulonbseg>6+20/60;20;1;0)/60)
Az első 3 sor a bementő adatokról szól.
A 4. sorban számoljuk a két időpont közötti különbséget a MARADÉK függvénnyel.
Az utolsó sorban a HAELSŐIGAZ megnézi hogy a különbség mekkora és levonja vagy a 45 vagy a 20 percet.üdv
-
-
dm1970
aktív tag
Sziasztok!
Egy kis segítségre, ötletre lenne szükségem, egyszerűen nem sikerül megoldást találnom. Több éve használok egy képletet, ami egy cellába beírt időpár alapján kiszámolja a tényleges munkaidőt a munkaközi szüneteket kiveszi belőle. Sajnos van benne hiba, s amikor ritkán beleszaladok vagy eszembe jut, megpróbálom a javítást, de nem jutok előrébb. A szabály, ha a munkaidő max 6 óra nincs szünet, ha meghaladja a 6 órát de max 9, akkor 20 perc a szünet, 9 óra felett 20+25. Tehát a két időpárt kivonom egymásból, eredmény =<6 nincs mínusz, 6<,<=9 -20, minden más esetben -45 perc.
Készítettem egy mintatáblázatot:
A végén látszanak a hibák, azt nem tudja kezelni a képletem, ha éjszakai 9 órát meg nem haladó munkavégzés van.
Bemásolom a képletet is, de lehet egyszerűbb egy új megközelítésből elindulni, már én sem mindig látom át, mit miért írtam bele. Jó lenne, ha a képlet, másolható lenne mindkét irányba.
=HA(BAL(B1;2)<BAL(JOBB(B1;5);2);((BAL(JOBB(B1;5);2))*60+(JOBB(B1;2))*1-(BAL(B1;2))*60-(BAL(JOBB(B1;8);2))*1-HA(ABS(((BAL(JOBB(B1;5);2))*60+(JOBB(B1;2))-BAL(B1;2)*60+(BAL(JOBB(B1;8);2)))/60)>9,34;45;HA(ABS(((BAL(JOBB(B1;5);2))*60+(JOBB(B1;2))-BAL(B1;2)*60+(BAL(JOBB(B1;8);2)))/60)<=6;0;20)))/60;((BAL(JOBB(B1;5);2))*60+(JOBB(B1;2))*1-(BAL(B1;2))*60-(BAL(JOBB(B1;8);2))*1-HA(ABS(((BAL(JOBB(B1;5);2))*60+(JOBB(B1;2))-BAL(B1;2)*60+(BAL(JOBB(B1;8);2)))/60)>9;45;HA(ABS(((BAL(JOBB(B1;5);2))*60+(JOBB(B1;2))-BAL(B1;2)*60+(BAL(JOBB(B1;8);2)))/60)<6;0;20)))/60+24)Köszi dm!
-
Delila_1
veterán
válasz
sopruk
#54602
üzenetére
Mindkét lapon számokká alakítottam a Termékkód oszlop adatait, elkerülendő, ha itt-ott akadna közöttük szöveg típusú. Egy cellába beírtam egy egyest, másoltam, majd irányítottan, szorzásként beillesztettem a jelölt helyekre. Ezután az FKERES függvény (HAHIBA függvénybe ágyazva) végzi a dolgát.
[data.hu] -
sopruk
senior tag
Sziasztok!
Az XKERES, FKERES, XHOL.VAN függvénnyel vannak gondjaim…
A data.hu-ra feltöltött tábla második, „CSV data” fülön lévő összeg oszlopot szeretném átvarázsolni az első „Terméklista” fülre, az első oszlopokban lévő Termékkódok alapján.
De valamiért nem látja őket semelyik függvény
Az FKERES-t rendszeresen használom kisebb tábláknál, ugyanazon program generálta táblázatok adatainak összefűzésére.
Most egy nagyobb adatbázist kellene hasonlóképpen összevezetni, de az egyik tábla máshonnan lett exportálva CSV formátumba.
Mindkét tábla sokkal nagyobb, a többi oszlopot kitöröltem a szemléltetéshez….
A CSV táblát már próbáltam többféle módon áthozni (mentés másként, kivágás-beillesztés, a jelenlegi táblában csak simán áthúztam a fület a csv táblából ebbe), hátha az a baj.
A cellákat is próbáltam módosítani általános-ra, szöveg-re, szám-ra…
Már több mint egy napom ráment a próbálgatásra, keresgélésre a neten, de nem találom a hiba okát
Van esetleg ötletetek, hogy mi lehet a probléma oka?
Előre is nagyon köszönöm! -
-
-
Nori0924
újonc
Köszönöm 😊
Vmit közben összehoztam én is, de én a "barkács" módszert hasznaltam.
A táblazaton kívüli cellákba a ma fgv, es a hónap utolsó napjai:2025.08.31, 2025.09.30...stb.
És így az adott honap oszlopát kijelölve ha fgv-nyel megoldottam vhogy. 🫣
De közben még azt nem tudom megoldani, hogy ha egy oszlopban van szám, szöveg és dátum is, akkor csak a számokat szummázza az oszlop alján. Erre van valami jó függvény? 🤔 -
#54594
Fire/SOUL/CD
félisten
Hátha valakinek jól jön: Office/Excel promók
-
lappy
őstag
válasz
Nori0924
#54588
üzenetére
Akkor a táblázat sem a legjobb ilyen szempontból
En a következőt tenném
A oszlop nevek
B oszloptol jönnek a hónapok
Valahova betennem a mai dátumot
Minden honap alatt képeznèk egy utolsó napot a Honapok nevei alapján
Ha ez megvan akkor ha a mai datum nagyobb mint a honap utolsó dátuma es a cella üres akkor piros legyen -
Nori0924
újonc
Úgy próbáltam volna megoldani, hogy a táblázaton kívül egy cellába beírom 08.31-et...de nem sikerült a képletet így összehoznom a feltételes formázásnál és egyébként sem jó az elgondolás mert akkor csak azon az egyetlen napon vizsgálja, szeptember 1-én már nem figyelmeztet a hátralékra a piros kitöltő színnel
-
Nori0924
újonc
Sziasztok,
Segítsetek pls! Az excelben hogyan tudom azt megoldani, hogy ha egy adott dátumon (pl 2025. augusztus 31-én) a cella üres, akkor a kitöltő szín váltson pirosra, és onnantól kezdve maradjon piros, amig érték nem kerül bele.
Egy tagdíj nyilvántartó táblához kellene, ha a hó utolsó napjáig nem kerül befizetésre a tagdíj, jelezze nekem a tábla.Köszi!
-
Fferi50
Topikgazda
válasz
Silious
#54580
üzenetére
Szia!
Csak makróval lehet megoldani, mert egy cella nem tartalmazhat képletet és számot is.
Én azt javaslom, hogy ne gombot tegyél a cellába, hanem csak egy plusz ill. mínusz jelet. A cellát akár színezheted is.
A cellára dupla kattintással kiváltod a növelést ill. csökkentést. Ehhez az alábbi makrót kell a munkalap kódlapjára bemásolnod:Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)If Target.Column = 1 ThenTarget.Offset(0, 1).Value = Target.Offset(0, 1).Value + 1End IfIf Target.Column = 3 ThenTarget.Offset(0, -1).Value = Target.Offset(0, -1).Value - 1End IfCancel = TrueEnd Sub
Az első oszlop bármelyik cellájába írhatod a + jelet ill. a harmadik oszlopba a - jelet. Mindegyikre működik a makró.
Figyelj rá, hogy hibakezelés és védelem nincs a makróban, tehát megváltoztathatók az értékek (a + és - jel is)!
Nálam így néz ki (az első sorba tettem, de bármelyik sorba teheted, a lényeg az A és C oszlop):
Üdv. -
Silious
tag
Sziasztok!
21-es Excelbe van arra valami megoldás, hogy az alábbi példában
Az A2 cellába egy - gomb, a C2 cellába egy + gomb kerüljön, olyan módon, hogy a B2-ben lévő 15-s számhoz vagy hozzáadjon, vagy elvegyen.
Ezt egy több száz soros oszlopba kellene megoldanom, hogy így könnyebben lehessen elvenni a számból és hozzáadni.
Ami csavar a dologba és itt akadtam meg igazából, hogy a B2-es cellába fontos, hogy mindenképp egy szám szerepeljen, ne képlet vagy egyéb, ugyanis ez a cella egy másik cellának a képlet része.
Van erre valami megoldás? -
#54578
Fferi50
Topikgazda
Sziszifeca
#54576
Fferi50
Topikgazda
válasz
Sziszifeca
#54576
üzenetére
Szia!
Solver használatával tudod megoldani. A Solvert először aktíválnod kell, a következőképpen:
Fejlesztőeszközök (ha nincs ilyen menücsoportod, akkor a Fájl - Beállítások - Menüszalag testreszabása - Fő lapok csoportnál be kell jelölnöd a Fejlesztőeszközök menüpont előtti négyzetet) menücsoportban az Excel bővítményeket megnyitod és bejelölöd a Solver bővítményt.
Ezután az Adatok menücsoport végén fogod megtalálni a Solvert.
Használatához elő kell készülni.
A B10 cellába beírod ezt a képletet:=SZORZATÖSSZEG($A$4:$A$9;B4:B9)-B3
amit áthúzol a C10 cellába is.
Ezután a két oszlopra külön-külön kell elvégezni az optimalizálást a Solverrel.
B oszlopra:
Célérték beállítása: $B$10 cella - értéke 0
Változó cellák módosításával: $B$4:$B$9
Vonatkozó korlátozások - hozzáadás
$B$4:$B$9 - bináris (ezt kell kiválasztanod).
Ezután rákattintasz a megoldásra és ahol 1 az érték, azok a számlák vannak benne az összegben.
Majd megcsinálod ugyanezt a C oszlopra értelemszerűen.
Megcsinálni gyorsabb, mint leírni. 
Persze, előfordulhat, hogy nem talál megoldást... akkor nem jók a számláid.
Üdv. -
#54577
Sziszifeca
őstag
Sziszifeca
#54576
Sziszifeca
őstag
válasz
Sziszifeca
#54576
üzenetére
Megoldva, kiszámoltattam nagy nehezen Chat gpt-vel.
-
#54576
Sziszifeca
őstag
Sziszifeca
őstag
Sziasztok!
Valami okos ember segítsen nekem
Próbálom egyszerűen leírni:
Amit meg kellene oldanom Excelben, hogy van egy pl. A. oszlop amibe számok vannak. Van 2db számla (pl. egyik 58200Ft, a másik 107100ft). Az A.oszlopban lévő összérték ennek a 2 számlának az összértéke.
Ki kellene válogatnom valahogyan hogy az A.oszlopban lévő számok közül, hogy melyik számok összege melyik számlához tartoznak.
Megpróbálom táblázatba bejelölni:
Ezt meg lehet egyáltalán oldani valami függvénnyel?
Ha igen valaki pl ezzel a példával megcsinálja egy xls fájlban és beteszi ide?
Köszönöm szépen aki segít!!! -
#54574
Mutt
senior tag
macilaci78
#54572
Mutt
senior tag
válasz
macilaci78
#54572
üzenetére
Szia,
Ha A1-ben van a cikkszám és soha nem tartalmazhat "|" és "#" (pipe és hashtag) jeleket, akkor B1-ben ez a képlet:
=HAHIBA(CSERE(BAL($A1;SZÖVEG.KERES("|";HELYETTE($A1&"-";"-";"|";OSZLOPOK($B:B)))-1);1;HAHIBA(SZÖVEG.KERES("#";HELYETTE($A1;"-";"#";OSZLOPOK($B:B)-1));0);"");"")Ezt tudod oldalra másolni, ahányszor kell az újabb részekért.
Excel 2010-ben teszteltem, jónak kell lennie 2016-ban is.A képlet működése:
1) van benne két HELYETTE amivel a kötőjeleket cserélgetjük le egyszer pipe-ra, ez fogja jelezni a szöveg minket érdeklő végét, illetve hashtag-re ami pedig a szöveg elejét jelzi. A HELYETTE függvényben meg lehet mondani, hogyha egy karakter többször előfordul, akkor melyik előfordulását cseréljük le. Az OSZLOPOK($B : B) adja meg, hogy éppen melyiket kell cserélni.
2) Ezek után már csak a két marker közötti szöveg kivágása van vissza. Előbb BAL-al levágjuk a végét (a pipe-jelig tartjuk meg a szöveget), majd a CSERE függvénnyel a hashtag-ig (ami a kezdetet jelöli) mindent semmire cserélünk.Másik megoldás pedig egy 2 soros Power Query lenne, de ez csak akkor ha sok adatod van.
Illetve VBA-val a Split függvénnyel pár soros kódot is lehetne használni.
üdv
-
#54573
lappy
őstag
macilaci78
#54572
lappy
őstag
válasz
macilaci78
#54572
üzenetére
Szövegből oszlopok
-
#54572
macilaci78
nagyúr
macilaci78
nagyúr
Sziasztok!
Van egy tételjegyzékem, aminek a cikkszám rovatában kötőjelekkel tagolt adatok vannak.
Például: BLC-DBE1-L05-P2R-A14130-F
Ezt szeretném szétdobni tagonként külön-külön oszlopba.
Office 2016-ban mi ennek a menete?Köszi előre is!
-
Mutt
senior tag
válasz
andreas49
#54568
üzenetére
Szia,
Remek.
A LET-ben is célszerű 365 helyett 365.25-el osztani, majd szorozni is.
A napokat pedig tehetjuk egy KEREKÍTÉS-be, ahogy gondolom te is tetted.
...napok;KEREKÍTÉS(eredmeny-evek)*365,25;0);...Illetve van egy másik megoldás is, ami a rejtett DÁTUMTÓLIG/DATEDIF függvényt használja. Ha van 2 dátumod (1900 utánból), akkor ezzel ki lehet számolni az eltelt évek és napok pontos számát.
=LET(adat1;A1;adat2;A2;evek;DÁTUMTÓLIG(adat1;adat2;"Y");napok;DÁTUMTÓLIG(DÁTUM(ÉV(adat1)+evek;HÓNAP(adat1);NAP(adat1));adat2;"D");evek&" ev"&IF(napok;" "&napok&" nap";""))üdv
-
Mutt
senior tag
válasz
andreas49
#54565
üzenetére
Szia,
Visszanézve a problémát a gond, hogy dátumokkal dolgozol, de az eredményed nem dátum, hanem a dátumok különbsége, így a formázás nem biztos hogy jó.
1) Azonban kipróbálhatod cella vagy SZÖVEG függvényben ezt a formázást: "? ?/365"
Az eredmény a fenti adatoknál ez lesz: "19 193/365", vagyis 19 év és 193 nap 365-ból.
Ha zavar a végén a "/365" rész, akkor kell egy hosszabb képlet.2) LET-nél szerintem az a gond, hogy az első két sorban olyan változók vannak, amelyeknél a pontos cellákat kell megadnod ahol az adataid vannak. A #hiányzik arra utal, hogy olyan cellákra hivatkozik ahol nincs adat.
Vagyis ha I2-ben van az 1999/01/01 és a másik dátumot L2 alapján találod meg, akkor így indul a képlet (aláhúzást tettem hogy feltünő legyen):
=LET(adat1;I2;
adat2;XKERES(L2;ALAP!$AA:$AA;ALAP!$AF:$AF); ....A LET-es képletet ha másolod, akkor a nem fixált cellahivatkozások (ahol nincs dollár jel) módosulnak, ezért célszerű a fixálni amit lehet.
=LET(adat1;$I2;adat2;XKERES($L2;Alap!$AA:$AA;Alap!$AF:$AF);atalakit;LAMBDA(x;DÁTUM(BAL(x;4);KÖZÉP(x;5;2);JOBB(x;2)));eredmeny;(atalakit(adat1)-atalakit(adat2))/365;evek;INT(eredmeny);napok;(eredmeny-evek)*365;evek&" év"&HA(napok;" "&napok&" nap";""))Az újabb Excelben a fenti hosszú képletből csinálhatunk egy saját függvényt a LAMBDA segítségével, ez talán zavaró lehet csak akkor írom ide ha akarod és egyedül nem tudod megcsinálni.
3) Ha nem akarsz LET-ezni akkor itt a csúnya képlet. 2x számolunk ki mindent, de először csak az éveket tartjuk meg (INT - egészrész), másodiknak pédig a tizedesrészt a napokhoz (MARADÉK). Itt ami még fontos, hogy a szökőévek miatt a 365-ös osztás nem elég pontos, 365.25-el 400 évig jók leszünk.
=SZÖVEGÖSSZEFŰZÉS(" ";TRUE;INT((DÁTUM(BAL($I2;4);KÖZÉP($I2;5;2);JOBB($I2;2))-DÁTUM(BAL(XKERES(L2;Alap!AA:AA;Alap!AF:AF);4);KÖZÉP(XKERES(L2;Alap!AA:AA;Alap!AF:AF);5;2);JOBB(XKERES(L2;Alap!AA:AA;Alap!AF:AF);2)))/365.25);"év";KEREKÍTÉS(MARADÉK((DÁTUM(BAL($I2;4);KÖZÉP($I2;5;2);JOBB($I2;2))-DÁTUM(BAL(XKERES(L2;Alap!AA:AA;Alap!AF:AF);4);KÖZÉP(XKERES(L2;Alap!AA:AA;Alap!AF:AF);5;2);JOBB(XKERES(L2;Alap!AA:AA;Alap!AF:AF);2)))/365.25;1)*365.25;0);"nap")
üdv -
andreas49
senior tag
Szia,
Köszi a gyors választ, beírtam a 'SZÖVEG' függvényt :=SZÖVEG(KEREKÍTÉS((DÁTUM(BAL($I2;4);KÖZÉP($I2;5;2);JOBB($I2;2))-DÁTUM(BAL(XKERES(L2;Alap!AA:AA;Alap!AF:AF);4);KÖZÉP(XKERES(L2;Alap!AA:AA;Alap!AF:AF);5;2);JOBB(XKERES(L2;Alap!AA:AA;Alap!AF:AF);2)))/365;1);"éé. nnn") de az eredmény 00. Cs lett a 19. év és 'Cs' nem pedig a napok száma
Az adatok ehhez az eredményhez: $I2 -> 19900101, 'AF:AF' -> 19700627
MS365 Excel HU programot használok -
Mutt
senior tag
Hasznos opciót adtak a legújabb Excelhez, egyelőre csak a beta tesztelőknek érhető el.
Mostantól a kimutatások/pivot automatikusan frissülhetnek amikor a forrásadatban változás van, ha ez engedélyezve van (alapból be van kapcsolva).
Módosítani kimutatásonként a beállításoknál az Adatok fülön lehet megtenni, vagy alapértelmezetten a Fájl -> Adatok -> Alapértelmezett elrendezés szerkesztése -> Kimutatás beállításai alatt lehet.
Sajna adatmodellt használó kimutatásokra nem érvényes ez a beállítás.
Remélem, tudod alkalmazni a saját táblázatodra. Ha nem sikerülne, küldd el privát üziben.
Megcsinálni gyorsabb, mint leírni. 
Új hozzászólás Aktív témák
- PC Game Pass előfizetés
- Játékkulcsok a legjobb áron: Steam
- Játékkulcsok olcsón: Steam, Uplay, GoG, Origin, Xbox, PS stb.
- Jogtiszta Windows - Office & Vírusirtó licencek- Azonnal - Számlával - Garanciával - Nint.hu
- 27%-OS ÁFÁS SZÁMLA I Jogtiszta Microsoft digitális és fizikai termékek I DIGITALKEYZ.COM
- Lenovo ThinkPad X270 (16) - i5-7300U, 16GB, 512GB SSD, 12" FULL HD (ELKELT)
- Bezámítás! Asus ROG STRIX G15 G513IH Gamer notebook - R7 4800H 16GB DDR4 512GB SSD GTX 1650 4GB W11
- DELL WD19S dokkoló + 130W töltő
- Telefon felvásárlás!! Samsung Galaxy A14/Samsung Galaxy A34/Samsung Galaxy A54
- Bomba ár! Dell Latitude 7390 - i7-8GEN I 16GB I 256GB SSD I 13,3" FHD I HDMI I Cam I W11 I Gari!
Állásajánlatok
Cég: FOTC
Város: Budapest