Új hozzászólás Aktív témák

• #54472 Mutt senior tag MCMLXXXII #54467

  Új Válasz 2025-06-06 16:09:00 #54472

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  Mutt

  senior tag

  válasz MCMLXXXII #54467 üzenetére

  Szia,

  Kaptál választ, de azért bedobok egy másikat is ami MS365 esetén használható.
  Tudunk olyan saját függvényt létrehozni, amivel egy cellából a számokat tartalmazó részt ki tudunk szedni. A REDUCE függvény tud segíteni.

  Ha A1-ben van az eredeti szöveg, akkor B1-ben a képlet megadja az eredményt:
  =REDUCE("";SORSZÁMLISTA(HOSSZ(A1));LAMBDA(a;c;a&HA(SZÁM(SZÖVEG.TALÁL(KÖZÉP(A1;c;1);"0123456789"));KÖZÉP(A1;c;1);"")))

  Egy kicsit rugalmassabbá lehet tenni, ha egy LAMBDA függvényt csinálunk. Ekkor a Névkezelőben kell elmenteni én a KINYER nevet adtam neki:
  =LAMBDA(
bemenet;
csak_szamok;
kiegeszito;
LET(h;HOSSZ(bemenet);
    formula;HA(csak_szamok;ELŐJEL;NEM);
    lista;"0123456789"&kiegeszito;
    r;REDUCE("";SORSZÁMLISTA(h);LAMBDA(a;c;a&HA(formula(SZÁM(SZÖVEG.TALÁL(KÖZÉP(bemenet;c;1);lista)));KÖZÉP(bemenet;c;1);"")));
  HAHIBA(r+0;r)
))

  3 paramétere van: az első az eredeti szöveget tartalmazó cella, a második egy 0 vagy 1 attól függően hogy a számok vagy a szöveg kell nekünk a cellából. A harmadik pedig egy karakter lista, amit a számokhoz fel akarunk pluszban venni (pl. tizedesvessző).

  

  A haladó Exceleseknek is szerintem rejt érdekességet a képlet.

  üdv

• #54468 Fferi50 Topikgazda MCMLXXXII #54467

  Új Válasz 2025-06-04 16:56:32 #54468

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  Fferi50

  Topikgazda

  válasz MCMLXXXII #54467 üzenetére

  Szia!
  Mi választja el a tételnevet a mennyiségtől? Mi van még közte, esetleg mértékegység?
  Üdv.

Új hozzászólás Aktív témák