Új hozzászólás Aktív témák

• #54476 Mutt senior tag pruzsi #54473

  Új Válasz 2025-06-07 01:37:31 #54476

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  Mutt

  senior tag

  válasz pruzsi #54473 üzenetére

  Szia,

  Megint az adatbázis függvényeket nyomatják, miközben a valós életben teljesen feleslegesek. No mindegy.

  Az eredeti fájl itt van: https://www.nkp.hu/tananyag/75215118658/download/T%C3%A1bl%C3%A1zatkezel%C3%A9s/felveteli.xlsx

  Csókoltatjuk aki
  1) felesleges szóközöket hagyott pár cellában (pl. F6, F12, F30).
  2) nem egyértelműen fogalmazta meg a kérdést.

  Kérdés:
  1) Példánkban az AB.MEZŐ alkalmazásánál miért nem elegendő csak a szóbeli pontszámot megadni, miért kell azzal az eredeti kritériumot bővíteni?
  A képlet hibát jelez, ha nincs az adott feltételnek megfelelő érték, vagy több ilyen is van.
  Azonban ilyen esetben is lehet több egyező érték (a mintában "véletlenül" nem ez az eset), ezért célszerübb előbb egy AB.DARAB-al lekérdezni a találatok számát és az alapján vagy üzenetet vagy az eredményt megjeleníteni. pl.
  =ÁTVÁLT(AB.DARAB2(A1:J151;"Név";N1:Q3);0;"Nincs találat";1;AB.MEZŐ(A1:J151;"Név";N1:Q3);"Több találat van")

  2) Vajon mi történik, ha a kritériumtartomány üres sort tartalmaz? Válaszunkat indokoljuk!
  Ahol nincs kereső kifejezés ott a teljes tartományt kapjuk vissza. Ha a kritérium teljesen üres, akkor az egész adatbázisból kapjuk meg az eredményt.

  3) Fejezzük be a feladatot a P7:Q10 tartományba írt képletek megadásával! Itt már elegendőek ugyan a „HATÖBB” függvények, de a feladatot oldjuk meg nemcsak azokkal, hanem az „AB” függvények alkalmazásával is!

  Ha itt a "teljes tagozat" a választott nyelvtől függetlenül "reál" tagozatos iskolásokat jelenti, akkor a Nyelv1 és Nyelv2 kritérium felesleges (ki is hagyható a kijelölésből, vagy üresen kell hagyni).
  P7-ben a képlet =AB.DARAB($A$1:$J$151;"Kód";$R$1:$R$2)
  A többi képlet látható fent.

  Bónusz: a feladatot oldjuk meg NE csak AB függvényekkel.
  a) HATÖBB-el.
  =DARABHATÖBB(D2:D151;"reál")
=ÁTLAGHATÖBB(G2:G151;D2:D151;"reál")
=MAXHA(G2:G151;D2:D151;"reál")
=MINHA(G2:G151;D2:D151;"reál")

  b) SZŰRŐ-vel
  =DARAB(SZŰRŐ(A2:A151;D2:D151="reál"))
=ÁTLAG(SZŰRŐ(G2:G151;D2:D151="reál"))
=MAX(SZŰRŐ(G2:G151;D2:D151="reál"))
=MIN(SZŰRŐ(G2:G151;D2:D151="reál"))

  Ha több feltétel alapján kell szűrni, akkor már bonyolultabb a dolog (pl. az eredeti kérdésben reál tagozat és német nyelv1 vagy nyelv2-ben). Itt felesleges szóköz miatt inkább KIMETSZ-be tettem mindent:
  =DARAB(SZŰRŐ(A2:A151;(KIMETSZ(D2:D151)="reál")*ELŐJEL((KIMETSZ(E2:E151)="német")+(KIMETSZ(F2:F151)="német"))))

  c) újabb függvény a CSOPORTOSÍTÁS.ALAP.SZERINT (GROUPBY), ahol 1 képlettel mind a 4 eredmény megkapható:
  

  A képlet pedig: =CSOPORTOSÍTÁS.ALAP.SZERINT(D1:D151;G1:G151;VÍZSZ.HALMOZÁS(DARAB;ÁTLAG;MAX;MIN);1;0;;D1:D151="reál")

  4) Csoportmunkában, a táblázatkezelő program alkalmazásával oldjuk meg a következő problémákat!
  a) válasz NEM, mivel LATIN nyelv esetén nincs meg az induló létszám.
  Ezt egy Kimutatás vagy az új Csoportosítás.alap.szerint tud segíteni.
  

  b) NEM, ha itt is 8 a minimum fő.
  Itt a képlet hosszú 3 indok miatt: 1) felesleges szóköz néha, 2) néha üres a nyelv2, 3) néha ugyanaz van a nyelv2-ben mint nyelv1-ben. Ezeket szűrtem ki, de KOREÁT nem változtatja meg.
  =CSOPORTOSÍTÁS.ALAP.SZERINT(KIMETSZ(F1:F151);KIMETSZ(F1:F151);DARAB2;3;0;2;(F1:F151<>"")*(KIMETSZ(E1:E151)<>KIMETSZ(F1:F151)))

  c) Amennyiben az iskolának takarékoskodnia kell, akkor milyen beosztásban indítható el a legkevesebb nyelvi csoport, ha a maximális csoportlétszám 24 fő?
  Ehhez vagy fáradt vagyok, vagy túlegyszerűsítem.
  Az a) kérdésben megnéztük hogy adott nyelv hányszor fordul elő elsődlegesen.
  7 nyelv van, van ahol csak 3 fő van van ahol több mint 24. Ha nincs induló létszám limit, akkor 10 csoport jön ki.
  

  üdv

• #54474 lappy őstag pruzsi #54473

  Új Válasz 2025-06-06 22:49:29 #54474

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  lappy

  őstag

  válasz pruzsi #54473 üzenetére

  Hogy válaszoljon hogyan kell használni a függvényt

Új hozzászólás Aktív témák