Új hozzászólás Aktív témák

• #19072 Mutt senior tag Sprite75 #19062

  Új Válasz 2013-09-26 22:10:26 #19072

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  Mutt

  senior tag

  válasz Sprite75 #19062 üzenetére

  Hello,

  ...a hónapok száma alapján kellene az adott hónap utolsó tankolási Km-ét kivonni az előző hónap utolsó tankolási Km-éből....

  Ez az én képletem az M8-as cellába:
  =(HAHIBA(INDEX(D:D;ÖSSZESÍT(14;6;SOR($G$2:$G$19)/($G$2:$G$19=J8);1));0)-HA(J8=1;$K$2;HAHIBA(INDEX(D:D;ÖSSZESÍT(14;6;SOR($G$2:$G$19)/($G$2:$G$19=J8-1);1));0)))*SZÁM(HOL.VAN(J8;G:G;0))*SZÁM(HA(J8=1;1;HOL.VAN(J8-1;G:G;0)))

  A működése:
  1. ÖSSZESÍT(14;6;SOR($G$2:$G$19)/($G$2:$G$19=J8);1)) kikeresi a hónap utolsó km sorának számát. pl. Április hónapnál 9-es sor.
  Az ÖSSZESÍT ezen felhasználását itt mutattam be, de ugyanerre juthatunk ezen képletekkel is,:
  =SZORZATÖSSZEG(MAX(($G:$G=J8)*SOR($G:$G)))
  {=MAX(HA((G:G=J8);SOR(G:G);0))}

  2. Ezt a sorszámot felhasználva INDEX függvénnyel kiolvassuk a D-oszlopból az értéket. Áprilisban ez 45205 lesz.
  3. Az egészet becsomagoljuk egy HAHIBA-ba, ahol hiba esetén 0-t kérünk vissza.
  4. Az első három lépést ugyanúgy lejátszuk, de eggyel korábbi hónappal (ugyanaz a képlet csak J8 helyett J8-1 -et használunk). pl. Március esetén az érték 43444 lesz.
  5. Itt még figyelembevesszük, hogy január esetén az előző évi óraállás kell K2-ből; ezt a HA(J8=1;K2;....) rész csinálja.
  6. A két számot kivonjuk egymásból. pl. 45205-43444=1761

  Kész is lennénk, ha minden hónapban és megelőző hónapban lenne érték, de ez nem garantált.
  7. Megnézzük, hogy a vizsgált hónap száma G oszlopban megtalálható-e a HOL.VAN függvénnyel. Ez egy számot add vissza ha ott van a keresett hónap. A SZÁM függvény tehát vagy IGAZ vagy HAMIS-ra fordítja le az eredményt.
  8. Ugyanezt megcsináljuk a megelőző hónapra, de itt még figyelünk arra hogy január előtti hónap is kezelve legyen.
  9. A 6-os lépésben kapott számot megszorozzuk a 7 és 8-as eredménnyel. pl. 1761*1*1=1761

  Március esetén a számok így jönnek ki:
  Március végi eredmény: 43444
  Február végi eredmény: 0 (mivel hibára fut a függvény és ekkor 0-t kapunk vissza).
  Március bent van a G oszlopban: IGAZ (1)
  Február bent van a G oszlopban: HAMIS (0)
  Az eredmény: (43444-0)*1*0 = 0

  üdv.

• #19068 Delila_1 veterán Sprite75 #19062

  Új Válasz 2013-09-26 17:01:02 #19068

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  Delila_1

  veterán

  válasz Sprite75 #19062 üzenetére

  Az M8 cella képlete legyen

  =HAHIBA(INDEX(D:G;HOL.VAN(J8;G:G;1);1)-INDEX(D:G;HOL.VAN(J8;G:G;0);1);"")

  ezt másold az alatta lévő cellákba.

• #19063 Sprite75 tag Sprite75 #19062

  Új Válasz 2013-09-26 15:30:04 #19063

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  Sprite75

  tag

  válasz Sprite75 #19062 üzenetére

  Valami megoldásfélét találtam, bár nem teljesen jó:
  {=MAX(HA($G:$G=J14;$D:$D))-(M8+M9+M10+M11+M13+M12+$K$2)}

  A havi legnagyobb km-ra állásból kivonja ez előző havi értékeket minusz az előző évi záró km-óra állást.
  Ez majdnem jó megoldás akkor ha van minden hónapban tankolás, de pl ennél az autónál is a februárnál minusz érték jönne ki ha a semmiből kivonja a januári futott km-ert. Ja és még azoknál a hónapoknál is hülyeséget számol ami még hátra van az évből. (8,9,10,11,12 hó)

  Szóval finomítani kellene a dolgon, vagy ha valakinek teljesen más ötlete van azt is szívesen fogadom

Új hozzászólás Aktív témák